Begining to request DBpedia Fr with SPARQL

Sparql is a language designed for querying knowledge bases. If you are already familiar with the SQL query language, SPARQL is very similar but adapted to the semantic web standards.

We advise you to consult the W3C recommendations page on SPARQL. It describes exhaustively the possibilities offered by the language. As concrete situation, we will focus today on the museum data of the French DBpedia chapter.

Before the first query

Before any exploration, you need to understand how the data are structured. The best solution is to visit the DBpedia Mapping wiki, which documents and lists the classes and the allowed properties you can associate with them.

Suppose you want to learn more about the artworks of each museum referenced on Wikipedia. It could be interesting to know who created them and when. Having a picture of the museum's location might be interesting if you plan to visit the nearest this weekend.

This time we make it easy for you by drawing the conceptual schema, based on what we could find on the DBpedia Mapping page, that will answer your questions :

First simple query

Now let's go on the French DBpedia endpoint ! As a warm-up, we will first ask DBpedia all the objects of the class Museum. You can write or copy/paste the following query to the Virtuoso editor.

                
                    PREFIX dbo: <http://dbpedia.org/ontology/>
                    
                    SELECT ?s WHERE {
                        ?s a dbo:Museum
                    }

You can notice that we use the keyword a between the subject ?s and the name of the classe. This is a shorthand for the property rdf:type. We also employed the prefix dbo, because that is faster than writting <http://dbpedia.org/ontology/Museum>, many other prefixes are registered in the virtuoso endpoint ( check the list here ). The following query is more verbose but equivalent to the previous one :

                
                    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
                    
                    SELECT ?s WHERE {
                        ?s rdf:type <http://dbpedia.org/ontology/Museum>
                    }

Exploring the Museums linked data

The list of the Museums

Now let's ask something more complex. We only want a list of the Museum located in France :

                
                    PREFIX dbo: <http://dbpedia.org/ontology/>
                    
                    SELECT DISTINCT ?s WHERE {
                        ?s a dbo:Museum.
                        ?s dbo:country <http://fr.dbpedia.org/resource/France>
                    }

Counting the number of Museum by city

Then let's count the number of the museum referenced by French cities.

                
                    PREFIX dbo: <http://dbpedia.org/ontology/>
                    
                    SELECT ?city ( COUNT ( DISTINCT ?s ) as ?nb ) WHERE {
                        ?s a dbo:Museum.
                         ?s dbo:country <http://fr.dbpedia.org/resource/France>.
                         ?s dbo:city ?city.

                    } GROUP BY ?city ORDER BY DESC(?nb)

You can notice that we selected in first instance the city of the French Museums and their names. It allowed us to group the results by city and count the number of museums they possess. And finally, notice that we also ordered the result by descending number of Museums.

Focus on Paris and some museum collections

Artwork and the available collections

We have understood that the majority of the French museums referenced are located in Paris. Now, we want to know how many collections and works of art each institution has.

We know in advance that some museums haven't defined collections on Wikipedia. For this reason, we will use the operator Optional, which allows us to return a result even for the museum without a specified collection.

                
                    PREFIX dbo:<http://dbpedia.org/ontology/>
                    
                    SELECT ?m ( COUNT( DISTINCT ?o ) as ?nb_artwork ) ( COUNT( DISTINCT ?col ) as ?nb_collection ) WHERE {
                        ?o a dbo:Artwork.
                        ?o dbo:museum ?m.
                        ?m dbo:city <http://fr.dbpedia.org/resource/Paris>.
                        OPTIONAL {?m dbo:collection ?col}
                    }  GROUP BY ?m ORDER BY DESC(?nb_artwork)

Filtering by date the artworks

Now we will explore the Louvre Museum collection of Artwork. Let's suppose that we want to filter it by creation date :

                
                    PREFIX dbo: <http://dbpedia.org/ontology/>
                    
                    PREFIX dbpedia-fr: 
                    SELECT  DISTINCT ?o  ?y WHERE {
                        ?o a dbo:Artwork.
                        ?o dbo:creationYear ?y.
                        FILTER( YEAR(?y) < 1900 && YEAR(?y) > 1850). 
                        ?o dbo:museum dbpedia-fr:Musée_du_Louvre.
                    }

The most referenced artists of the Louvre

Suppose we wanna get the ordered list of numbers of artworks found by artists in the Louvre Museum :

                
                    PREFIX dbo: <http://dbpedia.org/ontology/>
                    PREFIX dbpedia-fr: <http://fr.dbpedia.org/resource/>
                    
                    SELECT ?a ( COUNT( ?o ) as ?nb ) WHERE {
                        ?o a dbo:Artwork.
                        ?o dbo:author ?a.
                        ?o dbo:museum dbpedia-fr:Musée_du_Louvre.
                    }   GROUP BY ?a ORDER BY DESC(?nb) LIMIT 10

Other usefull SPARQL statements

Describing a ressource

For getting all statements known related to a resource use the Describe clause :

                
                DESCRIBE <http://fr.dbpedia.org/resource/Eugène_Delacroix>

Checking the existence of a fact

If you simply want to know if a resource exists, simply use the Ask clause :

                
                PREFIX dbo: <http://dbpedia.org/ontology/>
                
                ASK {
                    ?o dbo:museum ?m.
                    ?m a dbo:Museum.
                    ?m dbo:city <http://fr.dbpedia.org/resource/Lyon>.
                    ?o a dbo:Artwork.
                    ?o dbo:author <http://fr.dbpedia.org/resource/Raphaël_(peintre)>
                }